receive html form like data

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;

	public class ReceiveForm extends Sprite
	{
		public function ReceiveForm()
		{
			trace("receive urlencoded parameters");	
			var request:URLRequest=new URLRequest("params.txt");
			var loader:URLLoader=new URLLoader();
			loader.dataFormat=URLLoaderDataFormat.VARIABLES;
			loader.addEventListener(Event.COMPLETE, onComplete);
			loader.addEventListener(IOErrorEvent.IO_ERROR, onError);
			
			loader.load(request);
			
			
		}
		
		private function onComplete(event:Event):void {
			var loader:URLLoader=URLLoader(event.target);
			var dataObject:Object=loader.data;
			for  (var key:String in dataObject) {
				trace(key+"=>"+dataObject[key]+" value type: "+typeof(dataObject[key]));
			}
			var multiple:Object=dataObject.select;
			for each (var item:String in multiple) {
				trace("item="+item);
			}
			trace("item[0]: "+multiple[0]); //one
			trace("item[1]: "+multiple[1]); //two

		}
		
		private function onError(event:Event):void {
			trace("Error in loading: "+event);
		}
	}
}

username=hello123&password=abc123&list=1,2,3,4,5,6&select=one&select=two

receive urlencoded parameters
username=>hello123 value type: string
select=>one,two value type: object
list=>1,2,3,4,5,6 value type: string
password=>abc123 value type: string
item=one
item=two
item[0]: one
item[1]: two